学习目标
完成本单元后，您将能够：
- 使用Apex元数据API从组织中检索元数据。
- 使用Apex元数据API更新元数据并部署到组织中。
解决常见的多组织安装问题
好的，有时间解决您在多组织环境中工作时可能遇到的常见问题。假设你有10个组织，每个在你做生意的国家之一。您使用托管软件包来更新组织。您已经为“帐户”创建了一个自定义字段，并且希望它显示在所有组织的页面布局中。
理想情况下，您希望进行这些更新，而无需在管理员的设置UI中创建重复的工作。我们来看看如何使用Apex元数据API自动化流程。
我们通过Apex代码来检索帐户页面布局的现有元数据，并使用新字段进行更新。然后我们创建一个部署元数据更新的Apex post安装脚本。我们不必将我们的区域添加到我们每个组织的帐户页面布局中，而只需升级我们的组织中的托管软件包。 Apex负责所有的工作，在幕后添加新的区域。
检索元数据并将自定义字段添加到布局
以下是检索帐户页面布局的当前元数据的一些示例代码。然后它使用元数据来定位页面布局的帐户信息部分。最后，它为自定义字段创建一个元数据布局项目，并将其添加到本节中的元数据布局项目列表中。
- 点击设置装置，然后点击开发者控制台，打开 Developer Console.
- 在开发者控制台中，点击 .
- 命名类UpdatePageLayout并单击 OK.
- 摆脱任何现有的代码，并复制并粘贴下面的示例代码。
public class UpdatePageLayout {
// 将自定义字段添加到页面布局
public Metadata.Layout buildLayout() {
// 检索帐户布局和部分
List<Metadata.Metadata> layouts =
Metadata.Operations.retrieve(Metadata.MetadataType.Layout,
new List<String> {'Account-Account Layout'});
Metadata.Layout layoutMd = (Metadata.Layout) layouts.get(0);
Metadata.LayoutSection layoutSectionToEdit = null;
List<Metadata.LayoutSection> layoutSections = layoutMd.layoutSections;
for (Metadata.LayoutSection section : layoutSections) {
if (System.equals(section.label, 'Account Information')) {
layoutSectionToEdit = section;
break;
}
}
// 添加左栏中“帐户信息”部分下的字段
List<Metadata.LayoutColumn> layoutColumns = layoutSectionToEdit.layoutColumns;
List<Metadata.LayoutItem> layoutItems = layoutColumns.get(0).layoutItems;
// 为自定义字段创建一个新的布局项目
Metadata.LayoutItem item = new Metadata.LayoutItem();
item.behavior = Metadata.UiBehavior.Edit;
item.field = 'AMAPI__Apex_MD_API_sample_field__c';
layoutItems.add(item);
return layoutMd;
}
}
注意
要使用这个类，请用您的名称空间和字段名称替换 ‘AMAPI__Apex_MD_API_sample_field__c’ .
有关Metadata名称空间中的类的更多信息，请参阅Apex开发人员指南。
提供一个回调类
现在我们已经创建了布局字段元数据，我们准备将元数据部署到我们的组织。由于部署是异步的，因此我们提供回调，以便在排队的部署完成时通知我们。回调类必须实现Metadata.DeployCallback接口。
注意
由于回调是在部署之后异步调用的，因此可能会有一个短暂的部署完成时间，但回调尚未调用。
在开发者控制台中，使用名称PostInstallCallback和下面的代码创建一个Apex类。
public class PostInstallCallback implements Metadata.DeployCallback {
public void handleResult(Metadata.DeployResult result,
Metadata.DeployCallbackContext context) {
if (result.status == Metadata.DeployStatus.Succeeded) {
// 部署成功，采取适当的行动。
System.debug('Deployment Succeeded!');
} else {
// 部署不成功，采取适当的行动。
System.debug('Deployment Failed!');
}
}
}Apex元数据API提供了Metadata.Operations.enqueueDeployment方法来将元数据部署到当前组织。当调用此方法时，部署请求将排队进行异步处理。
注意
部署元数据时，您可以创建和更新组件，但不能删除它们。
使用以下代码创建名称为DeployMetadata的Apex类。这个类创建一个部署容器，并将新的布局元数据添加到它。它实例化我们的回调类，当部署完成时调用它。然后调用Metadata.Operations.enqueueDeployment方法将新的元数据部署到组织中。
public class DeployMetadata {
// 创建元数据容器
public Metadata.DeployContainer constructDeploymentRequest() {
Metadata.DeployContainer container = new Metadata.DeployContainer();
// 添加组件到容器
Metadata.Layout layoutMetadata = new UpdatePageLayout().buildLayout();
container.addMetadata(layoutMetadata);
return container;
}
// 部署元数据
public void deploy(Metadata.DeployContainer container) {
// 创建回调
PostInstallCallback callback = new PostInstallCallback();
// 使用新组件部署容器。
Id asyncResultId = Metadata.Operations.enqueueDeployment(container, callback);
}
}异步部署元数据
现在我们已经编写了我们需要的Apex类，我们可以部署我们的自定义元数据。我们从后安装脚本启动部署，后者是一个实现InstallHandler接口的Apex类。如果软件包包含安装后脚本，则在安装或升级软件包后脚本将自动运行。在Developer Console中，创建PostInstallScript Apex类。
public class PostInstallScript implements InstallHandler {
// 部署安装后的元数据
public void onInstall(InstallContext context) {
DeployMetadata deployUtil = new DeployMetadata();
Metadata.DeployContainer container = deployUtil.constructDeploymentRequest();
deployUtil.deploy(container);
}
}您可以在安装后脚本中检索和部署元数据。但是，在卸载脚本中，您可以从Apex代码中检索元数据，但不能部署元数据。
而已！当您在每个组织中升级软件包时，此脚本会将您的新字段添加到所有页面布局。您（和您的管理员）不必在安装界面中进行单一更改。在下一个单元中，我们看一个不同的场景。当你创建一个需要配置并部署到多个组织的自定义元数据类型时会发生什么？
但首先，试试看。完成以下挑战来测试你的知识。